home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Software Vault: The Gold Collection
/
Software Vault - The Gold Collection (American Databankers) (1993).ISO
/
cdr31
/
zip2zi31.zip
/
ZIP2ZIPD.BAT
< prev
next >
Wrap
DOS Batch File
|
1993-05-31
|
2KB
|
74 lines
@Echo off
Rem Zip2zipD.Bat (Called by Zip2zipC.Bat)
Rem %1 Starting Drive & Sub Dir (D:\SubDir\)
Rem %2 The Zip Within A Zip (In \Z_C) To Do Yet includes %1Z_B\Z_C\xx.zip
Rem ..Add/Change -options for Strip/Add Comment File, Logo etc.
Echo Zip2ZipD Executing on %2.
IF Exist %1Z_B\CNZL.FLG Set CNZL=Y
IF Exist %1Z_B\CNZL.FLG GoTo Done
IF NOT "%DONE_C%"=="" GoTo End
PKUNZIP %2 -t >Nul
IF Errorlevel 1 GoTo Error
Call ZIP2-ZNP.BAT %2
IF "%FSIZE%"=="" GoTo MajorError
IF "%FSIZE%"=="0" GoTo UN_ZIP
Set CNZL=Y
Echo %CNZL% >%1Z_B\CNZL.FLG
Echo %2 Is Too Deep..And Contains a .ZIP file In Path.>>%1ZIP2ZIP.LOG
Echo %2 Failed. See ZIP2ZIP.LOG
GoTo Done
:UN_ZIP
PKunZip %2 -d -Jhrs %1Z_B\Z_C\Z_D
IF Errorlevel 1 GoTo Error
IF Exist %1Z_B\Z_C\Z_D\*.ZIP GoTo ZIP_IN
Rem =============================================================
PKZip %2 -k -mrp -ex -Jhrs -wHS %1Z_B\Z_C\Z_D\*.*
IF Errorlevel 1 GoTo Error
Echo %2 Converted ok at 3rd level
Echo %2 Converted ok at 3rd level >>%1ZIP2ZIP.LOG
GoTo Done
Rem =============================================================
:ZIP_IN
Echo %2 Is Nested Too Deep To Process..! (3rd Lev) >>%1ZIP2ZIP.LOG
Echo %2 Is Nested Too Deep To Process..! (3rd Lev)
Set CNZL=Y
Echo %CNZL% >%1Z_B\CNZL.FLG
GoTo Done
:MajorError
Echo Major Logic Error. Do NOT Continue.
Set CNZL=Y
Echo %CNZL% >%1Z_B\CNZL.FLG
IF "%Safety%"=="" GoTo End
Echo Cancel With ^C (Control C)...Or...
Pause
Set Safety=
GoTo End
:Error
Echo %2 Failed... PKZIP or PKUNZIP Encountered an Error in 3rd Lev)>>%1\ZIP2ZIP.LOG
Set CNZL=Y
Echo %CNZL% >%1Z_B\CNZL.FLG
:Done
Call ZIP2ZMOP.BAT %1 Z_B\Z_C Z_D %CNZL%
Echo %2 >>#AT_C.
Type #AT_C. | FIND /C ".ZIP" >#DONE_C.
Echo N| COMP #2DO_C. #DONE_C. | FIND "OK" >ZIP2-FSZ.
CALL ZIP2-FSZ.BAT
IF "%FSIZE%"=="" GoTo MajorError
IF "%FSIZE%"=="0" GoTo End
Set DONE_C=Y
:End